From: Pushbutton Debounce (I slightly modified the code)

// =======================================================================
//  Debounce
//
//  Each time the input pin goes from LOW to HIGH (e.g. because of a push-button
//  press), the output pin is toggled from LOW to HIGH or HIGH to LOW. To ignore
//  There is a minimum delay between toggles.
//
//  The circuit:
//  - LED attached from pin 13 to ground
//  - pushbutton attached from pin 2 to +5V
//  - 10 kilohm resistor attached from pin 2 to ground
//
//  created 21 Nov 2006
//  by David A. Mellis
//  modified 30 Aug 2011
//  by Limor Fried
//  modified 28 Dec 2012
//  by Mike Walters
//  modified 30 Aug 2016
//  by Arturo Guadalupi
// =======================================================================

const int buttonPin =  2;    // pushbutton pin
const int ledPin    = 13;    // LED pin

int ledState        = HIGH;  // the current state of the output pin
int buttonState;             // the current reading from the input pin
int lastButtonState = LOW;   // the previous reading from the input pin

unsigned long lastDebounceTime =  0;  // the last time the output pin was toggled
unsigned long debounceDelay    = 50;  // the debounce time; increase if the output flickers

void setup()
{
  pinMode(buttonPin,   INPUT);
  pinMode(ledPin,      OUTPUT);
  digitalWrite(ledPin, ledState);
}

void loop()
{
  // read the state of the switch
  int reading = digitalRead(buttonPin);

  // check to see if you just pressed the button
  // (i.e. the input went from LOW to HIGH), and you've waited long enough
  // since the last press to ignore any noise:

  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState)
  {
    // reset the debouncing timer
    lastDebounceTime = millis();
  }

  if ((millis() - lastDebounceTime) > debounceDelay)
  {
    // whatever the reading is at, it's been there for longer than
    // DebounceDelay, so take it as the actual current state:

    // if the button state has changed:
    if (reading != buttonState)
    {
      buttonState = reading;

      // only toggle the LED if the new button state is HIGH
      if (buttonState == HIGH)
      {
        ledState = !ledState;
      }
    }
  }

  // set the LED:
  digitalWrite(ledPin, ledState);

  // save the reading. Next time through the loop, it'll be the lastButtonState:
  lastButtonState = reading;
}